128 lines
4.4 KiB
GLSL
128 lines
4.4 KiB
GLSL
//This shader file is part of FLAR - Advanced Renderer for Freelancer by Schmackbolzen
|
|
//If you use the supplied shader files you may not modify them unless you state in them what you changed
|
|
//and also mention the source or who the author is.
|
|
//Code based on https://learnopengl.com/PBR/IBL/Specular-IBL
|
|
|
|
|
|
#version 330
|
|
in vec2 TexCoords;
|
|
|
|
const float PI = 3.14159265359;
|
|
// ----------------------------------------------------------------------------
|
|
// http://holger.dammertz.org/stuff/notes_HammersleyOnHemisphere.html
|
|
// efficient VanDerCorpus calculation.
|
|
float RadicalInverse_VdC(uint bits)
|
|
{
|
|
bits = (bits << 16u) | (bits >> 16u);
|
|
bits = ((bits & 0x55555555u) << 1u) | ((bits & 0xAAAAAAAAu) >> 1u);
|
|
bits = ((bits & 0x33333333u) << 2u) | ((bits & 0xCCCCCCCCu) >> 2u);
|
|
bits = ((bits & 0x0F0F0F0Fu) << 4u) | ((bits & 0xF0F0F0F0u) >> 4u);
|
|
bits = ((bits & 0x00FF00FFu) << 8u) | ((bits & 0xFF00FF00u) >> 8u);
|
|
return float(bits) * 2.3283064365386963e-10; // / 0x100000000
|
|
}
|
|
// ----------------------------------------------------------------------------
|
|
vec2 Hammersley(uint i, uint N)
|
|
{
|
|
return vec2(float(i)/float(N), RadicalInverse_VdC(i));
|
|
}
|
|
// ----------------------------------------------------------------------------
|
|
vec3 ImportanceSampleGGX(vec2 Xi, vec3 N, float roughnessSquared)
|
|
{
|
|
//float a = roughness*roughness;
|
|
float a = roughnessSquared;
|
|
|
|
float phi = 2.0 * PI * Xi.x;
|
|
float cosTheta = sqrt((1.0 - Xi.y) / (1.0 + (a*a - 1.0) * Xi.y));
|
|
float sinTheta = sqrt(1.0 - cosTheta*cosTheta);
|
|
|
|
// from spherical coordinates to cartesian coordinates - halfway vector
|
|
vec3 H;
|
|
H.x = cos(phi) * sinTheta;
|
|
H.y = sin(phi) * sinTheta;
|
|
H.z = cosTheta;
|
|
|
|
// from tangent-space H vector to world-space sample vector
|
|
vec3 up = abs(N.z) < 0.999 ? vec3(0.0, 0.0, 1.0) : vec3(1.0, 0.0, 0.0);
|
|
vec3 tangent = normalize(cross(up, N));
|
|
vec3 bitangent = cross(N, tangent);
|
|
|
|
vec3 sampleVec = tangent * H.x + bitangent * H.y + N * H.z;
|
|
return normalize(sampleVec);
|
|
}
|
|
// ----------------------------------------------------------------------------
|
|
float GeometrySchlickGGX(float NdotV, float roughness)
|
|
{
|
|
// note that we use a different k for IBL
|
|
float a = roughness;
|
|
float k = (a * a) / 2.0;
|
|
|
|
float nom = NdotV;
|
|
float denom = NdotV * (1.0 - k) + k + 0.00001; // 0.00001 to prevent divide by zero.
|
|
|
|
return nom / denom;
|
|
}
|
|
// ----------------------------------------------------------------------------
|
|
float GeometrySmith(float NdotV, float NdotL, float roughness)
|
|
{
|
|
float ggx2 = GeometrySchlickGGX(NdotV, roughness);
|
|
float ggx1 = GeometrySchlickGGX(NdotL, roughness);
|
|
|
|
return ggx1 * ggx2;
|
|
}
|
|
//"PBR Diffuse Lighting for GGX+Smith Microsurfaces", Earl Hammon, Jr.
|
|
float GeometrySmithG2Hammon(float NdotV, float NdotL, float roughnessSquared)
|
|
{
|
|
float nom = 2*NdotL*NdotV;
|
|
float denom = mix(2*NdotL*NdotV,NdotL+NdotV,roughnessSquared) + 0.00001; // 0.00001 to prevent divide by zero.
|
|
return nom/denom;
|
|
}
|
|
|
|
// ----------------------------------------------------------------------------
|
|
vec2 IntegrateBRDF(float NdotV, float roughness)
|
|
{
|
|
vec3 V;
|
|
V.x = sqrt(1.0 - NdotV*NdotV);
|
|
V.y = 0.0;
|
|
V.z = NdotV;
|
|
|
|
float A = 0.0;
|
|
float B = 0.0;
|
|
|
|
vec3 N = vec3(0.0, 0.0, 1.0);
|
|
|
|
float roughnessSquared = roughness*roughness;
|
|
|
|
const uint SAMPLE_COUNT = 1024u;
|
|
for(uint i = 0u; i < SAMPLE_COUNT; ++i)
|
|
{
|
|
// generates a sample vector that's biased towards the
|
|
// preferred alignment direction (importance sampling).
|
|
vec2 Xi = Hammersley(i, SAMPLE_COUNT);
|
|
vec3 H = ImportanceSampleGGX(Xi, N, roughnessSquared);
|
|
vec3 L = normalize(2.0 * dot(V, H) * H - V);
|
|
|
|
float NdotL = max(L.z, 0.0);
|
|
|
|
if(NdotL > 0.0)
|
|
{
|
|
float NdotH = max(H.z, 0.0);
|
|
float VdotH = max(dot(V, H), 0.0);
|
|
//float G = GeometrySmith(NdotV, NdotL, roughness);
|
|
float G = GeometrySmithG2Hammon(NdotV, NdotL, roughnessSquared);
|
|
float G_Vis = (G * VdotH) / (NdotH * NdotV);
|
|
float Fc = pow(1.0 - VdotH, 5.0);
|
|
|
|
A += (1.0 - Fc) * G_Vis;
|
|
B += Fc * G_Vis;
|
|
}
|
|
}
|
|
A /= float(SAMPLE_COUNT);
|
|
B /= float(SAMPLE_COUNT);
|
|
return vec2(A, B);
|
|
}
|
|
// ----------------------------------------------------------------------------
|
|
void main()
|
|
{
|
|
vec2 integratedBRDF = IntegrateBRDF(TexCoords.x, TexCoords.y);
|
|
gl_FragColor.rg = integratedBRDF;
|
|
} |